9dc4952665
* To do so, we need to ensure that the generated kubeconfig is part of terraforms dependency graph. This has the additional benefit of not depending on local files anymore which should enable multi-user setups. * This also means that we can't deploy CCM, CSI & Traefik from our local host, because we don't have kubeconfig.yaml locally while provisioning the control plane, only afterwards. * So we just run kubectl apply on the control plane itself, after k3s is ready. * To do so, we need to deploy all manifests. I've merged the patches into a single kustomization.yaml file, because that makes the deployment of those files to the control-plane server easier. * we could also put the traefik config into the same kustomization file, which would save us one of the file provisioner blocks. I didn't want this PR to get any bigger, and will consider merging this config later on. kustomization.yaml is small enough that we could yamlencode() for it and store the patches in separate files again, not as inline-strings which is kind of ugly.
29 lines
1.1 KiB
HCL
29 lines
1.1 KiB
HCL
|
|
data "remote_file" "kubeconfig" {
|
|
conn {
|
|
host = hcloud_server.first_control_plane.ipv4_address
|
|
port = 22
|
|
user = "root"
|
|
private_key = local.ssh_private_key
|
|
agent = var.private_key == null
|
|
}
|
|
path = "/etc/rancher/k3s/k3s.yaml"
|
|
}
|
|
|
|
locals {
|
|
kubeconfig_external = replace(data.remote_file.kubeconfig.content, "127.0.0.1", hcloud_server.first_control_plane.ipv4_address)
|
|
kubeconfig_parsed = yamldecode(local.kubeconfig_external)
|
|
kubeconfig_data = {
|
|
host = local.kubeconfig_parsed["clusters"][0]["cluster"]["server"]
|
|
client_certificate = base64decode(local.kubeconfig_parsed["users"][0]["user"]["client-certificate-data"])
|
|
client_key = base64decode(local.kubeconfig_parsed["users"][0]["user"]["client-key-data"])
|
|
cluster_ca_certificate = base64decode(local.kubeconfig_parsed["clusters"][0]["cluster"]["certificate-authority-data"])
|
|
}
|
|
}
|
|
|
|
resource "local_file" "kubeconfig" {
|
|
sensitive_content = local.kubeconfig_external
|
|
filename = "kubeconfig.yaml"
|
|
file_permission = "600"
|
|
}
|