Move tests plan from dagger dir to universe

Signed-off-by: Tom Chauveau <tom.chauveau@epitech.eu>

stdlib/aws/ecr/tests/ecr.cue

@@ -0,0 +1,87 @@
+package ecr
+
+import (
+	"dagger.io/aws"
+	"dagger.io/dagger/op"
+	"dagger.io/random"
+)
+
+TestConfig: awsConfig: aws.#Config & {
+	region: "us-east-2"
+}
+
+TestECR: {
+	suffix: random.#String & {
+		seed: ""
+	}
+
+	repository: "125635003186.dkr.ecr.\(TestConfig.awsConfig.region).amazonaws.com/dagger-ci"
+	tag:        "test-ecr-\(suffix.out)"
+
+	creds: #Credentials & {
+		config: TestConfig.awsConfig
+	}
+
+	push: {
+		ref: "\(repository):\(tag)"
+
+		#up: [
+			op.#DockerBuild & {
+				dockerfile: """
+				FROM alpine
+				RUN echo \(suffix.out) > /test
+				"""
+			},
+
+			op.#DockerLogin & {
+				target:   repository
+				username: creds.username
+				secret:   creds.secret
+			},
+
+			op.#PushContainer & {
+				"ref": ref
+			},
+		]
+	}
+
+	pull: #up: [
+		op.#DockerLogin & {
+			target:   push.ref
+			username: creds.username
+			secret:   creds.secret
+		},
+
+		op.#FetchContainer & {
+			ref: push.ref
+		},
+	]
+
+	verify: #up: [
+		op.#Load & {
+			from: pull
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"sh", "-c", "test $(cat test) = \(suffix.out)",
+			]
+		},
+	]
+
+	verifyBuild: #up: [
+		op.#DockerLogin & {
+			target:   push.ref
+			username: creds.username
+			secret:   creds.secret
+		},
+
+		op.#DockerBuild & {
+			dockerfile: #"""
+				FROM \#(push.ref)
+				RUN test $(cat test) = \#(suffix.out)
+			"""#
+		},
+	]
+}

stdlib/aws/eks/tests/eks.cue

@@ -0,0 +1,52 @@
+package eks
+
+import (
+	"dagger.io/aws"
+	"dagger.io/kubernetes"
+	"dagger.io/dagger/op"
+)
+
+TestConfig: awsConfig: aws.#Config & {
+	region: "us-east-2"
+}
+
+TestCluster: #KubeConfig & {
+	config:      TestConfig.awsConfig
+	clusterName: *"dagger-example-eks-cluster" | string
+}
+
+TestEks: {
+	#GetPods:
+		"""
+			kubectl get pods -A
+			"""
+
+	#up: [
+		op.#Load & {
+			from: kubernetes.#Kubectl
+		},
+
+		op.#WriteFile & {
+			dest:    "/kubeconfig"
+			content: TestCluster.kubeconfig
+		},
+
+		op.#WriteFile & {
+			dest:    "/getPods.sh"
+			content: #GetPods
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/getPods.sh",
+			]
+			env: KUBECONFIG: "/kubeconfig"
+		},
+	]
+}

stdlib/aws/s3/tests/s3.cue

@@ -0,0 +1,37 @@
+package s3
+
+import (
+	"dagger.io/dagger"
+	"dagger.io/aws"
+)
+
+TestConfig: awsConfig: aws.#Config & {
+	region: "us-east-2"
+}
+
+bucket: "dagger-ci"
+
+content: "A simple test sentence"
+
+TestDirectory: dagger.#Artifact
+
+TestS3Object: {
+	deploy: #Object & {
+		always: true
+		config: TestConfig.awsConfig
+		source: TestDirectory
+		target: "s3://\(bucket)/"
+	}
+
+	verifyFile: #VerifyS3 & {
+		config: TestConfig.awsConfig
+		target: deploy.target
+		file:   "dirFile.txt"
+	}
+
+	verifyDir: #VerifyS3 & {
+		config: TestConfig.awsConfig
+		target: deploy.target
+		file:   "foo.txt"
+	}
+}

stdlib/aws/s3/tests/verify.cue

@@ -0,0 +1,83 @@
+package s3
+
+import (
+	"alpha.dagger.io/aws"
+	"alpha.dagger.io/alpine"
+	"alpha.dagger.io/dagger/op"
+)
+
+#List: {
+	// AWS Config
+	config: aws.#Config
+
+	// Target S3 URL (e.g. s3://<bucket-name>/<path>/<sub-path>)
+	target?: string
+
+	contents: {
+		string
+
+		#up: [
+			op.#Load & {
+				from: aws.#CLI & {
+					"config": config
+				}
+			},
+
+			op.#Exec & {
+				args: [
+					"/bin/bash",
+					"--noprofile",
+					"--norc",
+					"-eo",
+					"pipefail",
+					"-c",
+					#"""
+					aws s3 ls --recursive \#(target) > /contents
+					"""#,
+				]
+			},
+
+			op.#Export & {
+				source: "/contents"
+				format: "string"
+			},
+		]
+	}
+}
+
+#VerifyS3: {
+	file:   string
+	config: aws.#Config
+	target: string
+
+	lists: #List & {
+		"config": config
+		"target": target
+	}
+
+	test: #up: [
+		op.#Load & {
+			from: alpine.#Image & {
+				package: bash: "~5.1"
+			}
+		},
+
+		op.#WriteFile & {
+			dest:    "/test"
+			content: lists.contents
+		},
+
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"-c",
+				"grep -q \(file) /test",
+			]
+		},
+	]
+}