Add test for kube-gcp cue-manifest step

Signed-off-by: Tom Chauveau <tom.chauveau@epitech.eu>

docs/learn/tests/kube-gcp/cue-manifest/config.cue

@@ -0,0 +1,25 @@
+package main
+
+import (
+	"alpha.dagger.io/gcp"
+	"alpha.dagger.io/gcp/gcr"
+	"alpha.dagger.io/gcp/gke"
+)
+
+// Value created for generic reference of `kubeconfig` in `todoapp.cue`
+kubeconfig: gkeConfig.kubeconfig
+
+// gcpConfig used for Google connection
+gcpConfig: gcp.#Config
+
+// gkeConfig used for deployment
+gkeConfig: gke.#KubeConfig & {
+	// config field references `gkeConfig` value to set in once
+	config: gcpConfig
+}
+
+// gcrCreds used for remote image push
+gcrCreds: gcr.#Credentials & {
+	// config field references `gcpConfig` value to set in once
+	config: gcpConfig
+}

docs/learn/tests/kube-gcp/cue-manifest/deployment.cue

@@ -0,0 +1,43 @@
+package main
+
+// Deployment template containing all the common boilerplate shared by
+// deployments of this application.
+#Deployment: {
+	// Name of the deployment. This will be used to label resources automatically
+	// and generate selectors.
+	name: string
+
+	// Container image.
+	image: string
+
+	// 80 is the default port.
+	port: *80 | int
+
+	// 1 is the default, but we allow any number.
+	replicas: *1 | int
+
+	// Deployment manifest. Uses the name, image, port and replicas above to
+	// generate the resource manifest.
+	manifest: {
+		apiVersion: "apps/v1"
+		kind:       "Deployment"
+		metadata: {
+			"name": name
+			labels: app: name
+		}
+		spec: {
+			"replicas": replicas
+			selector: matchLabels: app: name
+			template: {
+				metadata: labels: app: name
+				spec: containers: [{
+					"name":  name
+					"image": image
+					ports: [{
+						containerPort: port
+					}]
+				}]
+			}
+		}
+	}
+}

docs/learn/tests/kube-gcp/cue-manifest/input.cue

@@ -0,0 +1,19 @@
+package main
+
+import (
+	"alpha.dagger.io/git"
+)
+
+manifest: git.#Repository & {
+	remote: "https://github.com/dagger/examples.git"
+	ref:    "main"
+	subdir: "todoapp/k8s"
+}
+
+repository: git.#Repository & {
+	remote: "https://github.com/dagger/examples.git"
+	ref:    "main"
+	subdir: "todoapp"
+}
+
+registry: "gcr.io/dagger-ci/test"

docs/learn/tests/kube-gcp/cue-manifest/manifest.cue

@@ -0,0 +1,29 @@
+package main
+
+import (
+	"encoding/yaml"
+)
+
+// Define and generate kubernetes deployment to deploy to kubernetes cluster
+#AppManifest: {
+	// Name of the application
+	name: string
+
+	// Image to deploy to
+	image: string
+
+	// Define a kubernetes deployment object
+	deployment: #Deployment & {
+		"name":  name
+		"image": image
+	}
+
+	// Define a kubernetes service object
+	service: #Service & {
+		"name": name
+		ports: http: deployment.port
+	}
+
+	// Merge definitions and convert them back from CUE to YAML
+	manifest: yaml.MarshalStream([deployment.manifest, service.manifest])
+}

docs/learn/tests/kube-gcp/cue-manifest/service.cue

@@ -0,0 +1,36 @@
+package main
+
+// Service template containing all the common boilerplate shared by
+// services of this application.
+#Service: {
+	// Name of the service. This will be used to label resources automatically
+	// and generate selector.
+	name: string
+
+	// NodePort is the default service type.
+	type: *"NodePort" | "LoadBalancer" | "ClusterIP" | "ExternalName"
+
+	// Ports where the service should listen
+	ports: [string]: number
+
+	// Service manifest. Uses the name, type and ports above to
+	// generate the resource manifest.
+	manifest: {
+		apiVersion: "v1"
+		kind:       "Service"
+		metadata: {
+			"name": "\(name)-service"
+			labels: app: name
+		}
+		spec: {
+			"type": type
+			"ports": [
+				for k, v in ports {
+					name: k
+					port: v
+				},
+			]
+			selector: app: name
+		}
+	}
+}

docs/learn/tests/kube-gcp/cue-manifest/test/test.cue

@@ -0,0 +1,66 @@
+package main
+
+import (
+	"alpha.dagger.io/dagger/op"
+	"alpha.dagger.io/kubernetes"
+)
+
+TestEks: {
+	#_GetDeployment: """
+			kubectl describe deployment todoapp | grep 'True'
+		"""
+
+	#_DeleteDeployment: """
+			kubectl delete deployment todoapp
+			kubectl delete service todoapp-service
+		"""
+
+	#up: [
+		op.#Load & {
+			from: kubernetes.#Kubectl
+		},
+
+		op.#WriteFile & {
+			dest:    "/kubeconfig"
+			content: todoApp.kubeSrc.kubeconfig
+		},
+
+		op.#WriteFile & {
+			dest:    "/getPods.sh"
+			content: #_GetDeployment
+		},
+
+		op.#WriteFile & {
+			dest:    "/deletePods.sh"
+			content: #_DeleteDeployment
+		},
+
+		// Get pods
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/getPods.sh",
+			]
+			env: KUBECONFIG: "/kubeconfig"
+		},
+
+		// Delete pods
+		op.#Exec & {
+			always: true
+			args: [
+				"/bin/bash",
+				"--noprofile",
+				"--norc",
+				"-eo",
+				"pipefail",
+				"/deletePods.sh",
+			]
+			env: KUBECONFIG: "/kubeconfig"
+		},
+	]
+}

docs/learn/tests/kube-gcp/cue-manifest/todoapp.cue

@@ -0,0 +1,45 @@
+package main
+
+import (
+	"alpha.dagger.io/dagger"
+	"alpha.dagger.io/docker"
+	"alpha.dagger.io/kubernetes"
+)
+
+// input: source code repository, must contain a Dockerfile
+// set with `dagger input dir repository . -e kube`
+repository: dagger.#Artifact & dagger.#Input
+
+// GCR registry to push images to
+registry: string & dagger.#Input
+tag:      "test-gcr"
+
+// Todoapp deployment pipeline
+todoApp: {
+	// Build the image from repositoru artifact
+	image: docker.#Build & {
+		source: repository
+	}
+
+	// Push image to registry
+	remoteImage: docker.#Push & {
+		target: "\(registry):\(tag)"
+		source: image
+		auth: {
+			username: gcrCreds.username
+			secret:   gcrCreds.secret
+		}
+	}
+
+	// Generate deployment manifest
+	deployment: #AppManifest & {
+		name:  "todoapp"
+		image: remoteImage.ref
+	}
+
+	// Deploy the customized manifest to a kubernetes cluster 
+	kubeSrc: kubernetes.#Resources & {
+		"kubeconfig": kubeconfig
+		manifest:     deployment.manifest
+	}
+}